#
# file:    main.gap
#
# purpose: Computations described in the paper
#          "Melikyan algebra is a deformation of a Poisson algebra".
#
# created: Pasha Zusmanovich <pasha.zusmanovich@gmail.com> Jan 7 2014
# 
# revision history:
# Sep 25 2014,Oct 25 2015  comments
#


Read ("poisson.gap");
Read ("meataxe.gap");

# divided powers algebras O_1(2), O_1(1) and O_2(1,1)
Ox := DividedPowersAlgebra (GF(5), 2);
Oy := DividedPowersAlgebra (GF(5), 1);
O := TensorProductOfAlgebras (Ox, Oy);

# d_x as a derivation of O_1(2) and O_2(2,1), and its powers
dx := Shift (Ox);
Dx := MapOtimesOne (O, dx);
d2 := CompositionMapping (dx, dx);
d3 := CompositionMapping (d2, dx);

# the algebra D as the sum of three structures
#
D := SumOfAlgebraStructures 
(
	# the algebra P
	PoissonAlgebra (O, Dx, OneOtimesMap (O, Shift (Oy))),

	# the cocyle phi
	PoissonAlgebra (O, MapOtimesOne (O, d2), MapOtimesOne (O, d3)),

	# 2*psi
	MultipleOfAlgebraStructure 
	(
		# the cocycle psi
		PoissonAlgebra (O,
			# id - xd_x 
			IdentityMapping (O) - CompositionMapping 
				(RightMult (O, CanonicalBasis (O)[2]), Dx),
			# d_x^5
			MapOtimesOne (O, CompositionMapping (d3, d2))), 
		2)
	);

# check that D satisfies the Jacobi identity
IsLieAlgebra (D);

# check that D is central simple
MeataxeIsCentralSimple (D);

# check that D is isomorphic to D^* as D-modules
MeataxeAdjointIsomToDual (D);

# end of main.gap